!src "../include/gmod3.inc"

        !cpu    6502
        
        *=    $0801
        !byte   $0b,$08               ;link to next line
        !byte   $40,$03               ;line-number
        !byte   $9e,$32,$30,$36,$31   ;"SYS 2061"
        !byte   0                     ;end of line
        !byte   0,0                   ;null-link, no more lines following

        jmp start

        !src "../lib/gmod3.asm"

;-------------------------------------------------------------------------------

start:

        ; just to place the cursor
        lda #$93
        jsr $ffd2

        sei
        ; clear screen
        ldx #0
-
        lda #$20
        sta $0400,x
        sta $0500,x
        sta $0600,x
        sta $0700,x
        lda #$01
        sta $d800,x
        sta $d900,x
        sta $da00,x
        sta $db00,x        
        inx
        bne -
        
        jsr flash_readid
        
;   A: manufacturer ID ($1c)
;   X: device ID ($70)
;   Y: capacity ($18/24 - 2^24, 16MB)
        
        stx devid
        sty flashsize
        
        ; manufacturer
        pha
        lsr
        lsr
        lsr
        lsr
        tay
        lda hexdigits,y
        sta $0400
        pla
        and #$0f
        tay
        lda hexdigits,y
        sta $0401

devid = * + 1
        lda #0
        pha
        lsr
        lsr
        lsr
        lsr
        tay
        lda hexdigits,y
        sta $0403
        pla
        and #$0f
        tay
        lda hexdigits,y
        sta $0404
        
flashsize = * + 1
        lda #0
        pha
        lsr
        lsr
        lsr
        lsr
        tay
        lda hexdigits,y
        sta $0406
        pla
        and #$0f
        tay
        lda hexdigits,y
        sta $0407
        
        jsr flash_wait_busy
        
        lda #5
        sta $d020
        
        lda #GMOD3_CTRL_8KGAME
        sta GMOD3_CTRL
        
        cli
        rts
        
hexdigits:
    !scr "0123456789abcdef"